Fail to start RapidMiner5 on Win XP 32bit.

todd1313

Thank you that you guys are interested in my issue. I am very begginer, so it makes me confused. I appreciate your help in advance.

Installation was completed properly, but I cannot run the program. When I double-click the icon at desktop, nothing happens. Even I try to open the program in console mode, it closes itself right after open DOS window. Could you give me any comments or suggestions?

Regards,
Jongone

Marco_Boeck

Hi,

can you check the 'C:\Users\XYZ\.RapidMiner5' folder for a 'rm.log' file and posts its content here?
If there is none or it is empty, please press 'Windows+R' on your keyboard, enter 'cmd', press 'Enter'. Then navigate to the folder you installed RapidMiner to, for example via 'cd "C:\Program Files\Rapid-I\RapidMiner5\scripts"'. Then enter 'RapidMinerGUI.bat', press 'Enter' again and post the text that appears here.

Regards,
Marco

todd1313

Thank you Marco for your quick response.

Here is the captured image.



c:\Program Files\Rapid-I\RapidMiner5\scripts>RapidMinerGUI.bat
RAPIDMINER_HOME is not set. Trying the directory 'c:\Program Files\Rapid-I\RapidMiner5\scripts\..'...
Using local jre: c:\Program Files\Rapid-I\RapidMiner5\scripts..\jre\bin\java.exe...
Starting RapidMiner from 'c:\Program Files\Rapid-I\RapidMiner5\scripts\..' using classes from 'c:\Program Files\Rapid-I\RapidMiner5\scripts\..\lib\rapidminer.jar'...
Creating file "c:\Documents and Settings\jongonei.ASURITE\Application Data\check_rm_java_version"
Java Version: 1.7.0_11
Removing file "C:\Documents and Settings\jongonei.ASURITE\Application Data\check_rm_java_version"
Starting in multicore mode with G1 garbage collector...
Error occured during initialization of VM
Could not reserve enough space for object heap

Marco_Boeck

Hi,

it seems you are lacking the required amount of memory. How much do you have?

Regards,
Marco

todd1313

It is 3.25GB(I think it means 4GB).
Do I need to add more memory?

Best,
Jongone

Marco_Boeck

Hi,

no that is more than enough to start RapidMiner (though your actual workflow might need much more later on ;D).
Can you try navigating to your RapidMiner/scripts folder, open the RapidMinerGUI.bat file with a text editor, edit the line 'MAX_JAVA_MEMORY=XYZ' so it says 'MAX_JAVA_MEMORY=1024' and try to start RapidMiner by double-clicking this very .bat file? It might be that the RapidMiner.exe for some reason uses not enough memory, and by starting RapidMiner with this script instead gives you full control over how much memory is available to RapidMiner.

Regards,
Marco

todd1313

Hi Marco,

Unfortunately, the script is already like what you posted. Such as the below,

rem ##########################################
rem ###                                    ###
rem ###  Setting Maximal Amount of Memory  ###
rem ###                                    ###
rem ##########################################

if "%MAX_JAVA_MEMORY%"=="" set MAX_JAVA_MEMORY=1024

Do you have any other trial solutions? I always appreciate to your help.

Best regards,
Jongone

Marco_Boeck

Hi,

is your 'MAX_JAVA_MEMORY' system variable set on your system? You can see if that is the case via typing 'echo %MAX_JAVA_MEMORY%' into the commandline. If so, you may need to edit the value of the variable.
If not, please try starting the RapidMinerGUI.bat script with an additional commandline parameter: '-XX:MaxHeapSize=256m'. This sets the heap size java has available.
Please also note that you cannot use more than ~1400MB of memory for RapidMiner if you are using Windows 32-bit because of various limitations.

Regards,
Marco

todd1313

Hi,

There is no 'echo %MAX_JAVA_MEMORY%' and '-XX:MaxHeapSize=256m' commandlines. Just to inform you, I copy and paste the whole RapidMinerGUI.bat script below.

Regards,
Jongone



@echo off
SETLOCAL ENABLEDELAYEDEXPANSION

rem ##############################################################
rem ###                                                        ###
rem ###            Windows Start Script for RapidMiner        ###
rem ###                                                        ###
rem ###  This script tries to determine the location of        ###
rem ###  RapidMiner, searches for a proper Java executable    ###
rem ###  and start the program.                                ###
rem ###                                                        ###
rem ###  Please adapt the line containing MAX_JAVA_MEMORY in  ###
rem ###  order to allow for more memory usage.                ###
rem ###  Alternatively, you can define an environment variable ###
rem ###  MAX_JAVA_MEMORY!                                      ###
rem ###                                                        ###
rem ###  You might also want to add a JDBC driver library in  ###
rem ###  the line with RAPIDMINER_JDBC_DRIVERS!                ###
rem ###                                                        ###
rem ##############################################################


rem ##########################################
rem ###                                    ###
rem ###  Setting Maximal Amount of Memory  ###
rem ###                                    ###
rem ##########################################

if "%MAX_JAVA_MEMORY%"=="" set MAX_JAVA_MEMORY=1024

rem ###########################################
rem ###                                    ###
rem ###  Setting Additional Operators Path  ###
rem ###                                    ###
rem ###########################################

if "%RAPIDMINER_OPERATORS_ADDITIONAL%"=="" set RAPIDMINER_OPERATORS_ADDITIONAL=


rem ##########################################
rem ###                                    ###
rem ###  Setting JDBC Driver Libraries    ###
rem ###                                    ###
rem ##########################################

if "%RAPIDMINER_JDBC_DRIVERS%"=="" set RAPIDMINER_JDBC_DRIVERS=


rem #############################################
rem ###                                      ###
rem ###  Setting or Guessing RAPIDMINER_HOME  ###
rem ###                                      ###
rem #############################################

rem ###  set RAPIDMINER_HOME to the correct directory if you changed the location of this start script  ###

if "%RAPIDMINER_HOME%"=="" goto guessrapidminerhome
goto javahome

:guessrapidminerhome
set RAPIDMINER_BATCHDIR=%~dp0
set RAPIDMINER_HOME=%RAPIDMINER_BATCHDIR%..
echo RAPIDMINER_HOME is not set. Trying the directory '%RAPIDMINER_HOME%'...
goto javahome


rem ############################
rem ###                      ###
rem ###  Searching for Java  ###
rem ###                      ###
rem ############################

:javahome
set LOCAL_JRE_JAVA=%RAPIDMINER_HOME%\jre\bin\java.exe
if exist "%LOCAL_JRE_JAVA%" goto localjre
goto checkjavahome

:localjre
set JAVA=%LOCAL_JRE_JAVA%
echo Using local jre: %JAVA%...
goto commandlinearguments

:checkjavahome
if "%JAVA_HOME%"=="" goto checkpath
set JAVA_CHECK=%JAVA_HOME%\bin\java.exe
if exist "%JAVA_CHECK%" goto globaljre
goto error3

:globaljre
set JAVA=%JAVA_HOME%\bin\java
echo Using global jre: %JAVA%...
goto commandlinearguments

:checkpath
java -version 2> nul:
if errorlevel 1 goto error2
goto globaljrepath

:globaljrepath
set JAVA=java
echo Using global jre found on path: %JAVA%
goto commandlinearguments


rem #########################################
rem ###                                  ###
rem ###  Handling Command Line Arguments  ###
rem ###                                  ###
rem #########################################

:commandlinearguments
set CMD_LINE_ARGS=
:args
if [%1]==[] goto update
set CMD_LINE_ARGS=%CMD_LINE_ARGS% %1
shift
goto args


rem ###########################
rem ###                    ###
rem ###  Performing Update  ###
rem ###                    ###
rem ###########################

:update
set RUINSTALL_DIR=%RAPIDMINER_HOME%\RUinstall
if exist "%RUINSTALL_DIR%" goto perform_update
goto start

:perform_update
xcopy "%RUINSTALL_DIR%" "%RAPIDMINER_HOME%" /c /s /y /i
rmdir "%RUINSTALL_DIR%" /s /q
goto start


rem #############################
rem ###                      ###
rem ###  Starting RapidMiner  ###
rem ###                      ###
rem #############################

:start
set RAPIDMINER_JAR=%RAPIDMINER_HOME%\lib\rapidminer.jar
set BUILD=%RAPIDMINER_HOME%\build
set RAPIDMINER_CLASSPATH=

if exist "%RAPIDMINER_JAR%" set RAPIDMINER_CLASSPATH=%RAPIDMINER_JAR%
if exist "%BUILD%" set RAPIDMINER_CLASSPATH=%BUILD%
if "%RAPIDMINER_CLASSPATH%"=="" goto error1

set RAPIDMINER_LIBRARIES=
for %%f in ("%RAPIDMINER_HOME%\lib\*.jar") do set RAPIDMINER_LIBRARIES=!RAPIDMINER_LIBRARIES!;%%f
for %%f in ("%RAPIDMINER_HOME%\lib\jdbc\*.jar") do set RAPIDMINER_LIBRARIES=!RAPIDMINER_LIBRARIES!;%%f
for %%f in ("%RAPIDMINER_HOME%\lib\freehep\*.jar") do set RAPIDMINER_LIBRARIES=!RAPIDMINER_LIBRARIES!;%%f

set COMPLETE_CLASSPATH=%RAPIDMINER_CLASSPATH%;%RAPIDMINER_LIBRARIES%
set JDBC_DRIVER_PARAMETER=

if not "%RAPIDMINER_JDBC_DRIVERS%"=="" set COMPLETE_CLASSPATH=%COMPLETE_CLASSPATH%;%RAPIDMINER_JDBC_DRIVERS%
if not "%RAPIDMINER_JDBC_DRIVERS%"=="" set RAPIDMINER_JDBC_DRIVER_PARAMETER=-Drapidminer.init.jdbc.location="%RAPIDMINER_JDBC_DRIVERS%"

echo Starting RapidMiner from '%RAPIDMINER_HOME%' using classes from '%RAPIDMINER_CLASSPATH%'...
rem echo The used classpath is '%COMPLETE_CLASSPATH%'...

:checkJavaVersion
set CHECK_VERSION_FILE="%APPDATA%\check_rm_java_version"
@echo Creating file %CHECK_VERSION_FILE%
"%JAVA%" -version 2>&1 | findstr /i "version" >  %CHECK_VERSION_FILE%

for /F "tokens=3" %%g in ('type %CHECK_VERSION_FILE%') do (
    set JAVAVER=%%g
)

set JAVAVER=%JAVAVER:"=%
@echo Java Version: %JAVAVER%

for /f "delims=. tokens=1-3" %%v in ("%JAVAVER%") do (
set JAVA_MAJOR=%%v
    set JAVA_MINOR=%%w
    set JAVA_BUILD=%%x
)

rem @echo Major: %JAVA_MAJOR%
rem @echo Minor: %JAVA_MINOR%
rem @echo Build: %JAVA_BUILD%

@echo Removing file %CHECK_VERSION_FILE%
del %CHECK_VERSION_FILE%

:launch
if %NUMBER_OF_PROCESSORS% GEQ 2 goto startMultiCoreMode
@echo Starting single core mode...
"%JAVA%" -Xms%MAX_JAVA_MEMORY%m -Xmx%MAX_JAVA_MEMORY%m -classpath "%COMPLETE_CLASSPATH%" -Drapidminer.home="%RAPIDMINER_HOME%" -Drapidminer.operators.additional="%RAPIDMINER_OPERATORS_ADDITIONAL%" %RAPIDMINER_JDBC_DRIVER_PARAMETER% -jar "%RAPIDMINER_HOME%\lib\launcher.jar" %CMD_LINE_ARGS%
goto startEnd

:startMultiCoreMode
SET /A NUMBER_OF_GC_THREADS=%NUMBER_OF_PROCESSORS%-1
if %JAVA_MINOR% GEQ 7 goto :startMultiCoreMode_withG1GC
@echo Starting in multicore mode with CMS garbage collector...
"%JAVA%" -XX:+UseParallelGC -XX:+UseParallelOldGC -XX:ParallelGCThreads=%NUMBER_OF_GC_THREADS% -Xms%MAX_JAVA_MEMORY%m -Xmx%MAX_JAVA_MEMORY%m -classpath "%COMPLETE_CLASSPATH%" -Drapidminer.home="%RAPIDMINER_HOME%" -Drapidminer.operators.additional="%RAPIDMINER_OPERATORS_ADDITIONAL%" %RAPIDMINER_JDBC_DRIVER_PARAMETER% -jar "%RAPIDMINER_HOME%\lib\launcher.jar" %CMD_LINE_ARGS%
goto startEnd

:startMultiCoreMode_withG1GC
@echo Starting in multicore mode with G1 garbage collector...
"%JAVA%" -XX:+UseG1GC -XX:MaxGCPauseMillis=50 -XX:InitiatingHeapOccupancyPercent=0 -XX:ConcGCThreads=%NUMBER_OF_GC_THREADS% -XX:ParallelGCThreads=%NUMBER_OF_PROCESSORS% -Xms%MAX_JAVA_MEMORY%m -Xmx%MAX_JAVA_MEMORY%m -classpath "%COMPLETE_CLASSPATH%" -Drapidminer.home="%RAPIDMINER_HOME%" -Drapidminer.operators.additional="%RAPIDMINER_OPERATORS_ADDITIONAL%" %RAPIDMINER_JDBC_DRIVER_PARAMETER% -jar "%RAPIDMINER_HOME%\lib\launcher.jar" %CMD_LINE_ARGS%
goto startEnd

:startEnd
if errorlevel 2 goto update
goto end


rem ########################
rem ###                  ###
rem ###  Error messages  ###
rem ###                  ###
rem ########################

:error1
echo.
echo ERROR: Neither
echo %RAPIDMINER_JAR%
echo nor
echo %BUILD%
echo was found.
echo If you use the source version of RapidMiner, try
echo 'ant build' or 'ant dist' first.
echo.
pause
goto end

:error2
echo.
echo ERROR: Java cannot be found.
echo Please install Java properly (check if JAVA_HOME is
echo correctly set or ensure that 'java' is part of the
echo PATH environment variable).
echo.
pause
goto end

:error3
echo.
echo ERROR: Java cannot be found in the path JAVA_HOME
echo Please install Java properly (it seems that the
echo environment variable JAVA_HOME does not point to
echo a Java installation).
echo.
pause
goto end

rem #############
rem ###      ###
rem ###  END  ###
rem ###      ###
rem #############

:end

Marco_Boeck

Hi,

please press 'Windows Key + R', then type 'cmd' and press 'Enter'. Afterwards type 'echo %MAX_JAVA_MEMORY%' and press 'Enter' again, and see if it just comes back as '%MAX_JAVA_MEMORY%' or as for example '256'. If you get a value, it means on your system the global system variable MAX_JAVA_MEMORY is set to a potentially too low value, which you would need to edit and change (as you did inside the script).
If you do not get a value, you will have to try the other suggestion:
Navigate to your RapidMiner/scripts folder within the commandline, for example via 'cd "C:\Program Files\Rapid-I\RapidMiner\scripts"' and then enter 'RapidMinerGUI.bat -XX:MaxHeapSize=256m' and press 'Enter' and see if that helps.

Regards,
Marco

todd1313

Hi Marco (again),

I didn't get a value and did what you informed me. It seems that it still does not work. Please check the below.

I appreciate your endless help.
Jongone



Microsoft Windows XP [Version 5.1.2600]
(C) Copyright 1985-2001 Microsoft Corp.

C:\Documents and Settings\jongonei.ASURITE>echo %MAX_JAVA_MEMORY%
%MAX_JAVA_MEMORY%

C:\Documents and Settings\jongonei.ASURITE>cd "C:\Program Files\Rapid-I\RapidMiner5\scripts"

C:\Program Files\Rapid-I\RapidMiner5\scripts>RapidMinerGUI.bat -XX:MaxHeapSize=256m
RAPIDMINER_HOME is not set. Trying the directory 'C:\Program Files\Rapid-I\RapidMiner5\scripts\..'...
Using local jre: C:\Program Files\Rapid-I\RapidMiner5\scripts\..\jre\bin\java.exe...
Starting RapidMiner from 'C:\Program Files\Rapid-I\RapidMiner5\scripts\..' using classes from 'C:\Program Files\Rapid-I\RapidMiner5\scripts\..\lib\rapidminer.jar'...
Creating file "C:\Documents and Settings\jongonei.ASURITE\Application Data\check_rm_java_version"
Java Version: 1.7.0_11
Removing file "C:\Documents and Settings\jongonei.ASURITE\Application Data\check_rm_java_version"
Starting in multicore mode with G1 garbage collector...
Error occurred during initialization of VM
Could not reserve enough space for object heap

C:\Program Files\Rapid-I\RapidMiner5\scripts>

Marco_Boeck

Hi,

generally speaking, the problem is caused when Java cannot find enough free memory to allocate for use. So my best guess is that you do not have enough free memory available. Apart from that, I'm also at a loss what might be causing your problem, I'm afraid..

Regards,
Marco

todd1313

Hi Marco,

I got it. I will figure out the available memory. or re-set up window or use other com.
I really appreciate your help, Marco.

Regards,
Jongone

armin

Run Rapidminer as Administrator and check if it works or not.